RSA procedure cryptology - encryption

Question

Hi i was wondering if anyone can help me with the following procedure using maple
The protocol of the rsa decryption/encryption method is below and the question i am trying to attempt after that with my attempt below it, i will appreciate any help. Thanks
my current attempt is the following
rsa := proc (key::rsakey, msg::(list(rsascii)))
local ct, pe, pm, i;
pm := 26271227347;
pe := key[2];
ct := [];
for i to nops(msg) do ct := [op(ct), `mod`(message[i]^pe, pm)]
end do;
RETURN(ct)
end proc;
this was from using the maple website

Answer 1

You've been given n and e, and you'll need to find the corresponding d before you can decode. I don't understand why you were trying to use e to decode.
Your procedure contains at least one type, using message[i] instead of msg[i]. See also comments in the code below.
After finding d I get that the encoded integer 11393739244 decodes to the integer 87, which corresponds to the ASCII character "W" (not "wha" or "Wha" as you suggested).
I don't understand what you intend on doing about block size, and so I've had to guess. Below I show encoding/decoding done either A) a character at a time, or B) using three characters at once. I trust you realize that encoding one-character-at-a-time isn't a great idea. Also, in a duplicate post in another forum you wrote that you don't care about security against attack. (You also wrote there that this isn't homework, but here it looks like it more, IMO.)
If you had trouble writing and using your rsa procedure then you may find the various splitting/concetenating/padding operations tough also.
You wrote in a comment that when you tried to use your initial attempt at procedure rsa then, "it doesn't give anything back". If it returned as an unevaluated call then perhaps your attempt at creating the proc and assigning it didn't actually work. If you have trouble using Maple's default 2D Input mode in a Document then consider switching your preferences to 1D Maple Notation input in a Worksheet. Those are two Preferences for Maple's Standard Java GUI.
NB. I use Maple's numtheory[lambda] command to find "the smallest integer i such that for all g coprime to n, g^i is congruent to 1 modulo n". In recent Maple versions this is also avaliable as the command NumberThoery:-CarmichaelLambda. See also here.
restart;
# The procedure `rsa` below can be used to both encode or
# decode an integer.
#
# Conversion from/to ASCII is done separately, before/after.
rsa := proc(key::list(posint), msg::list(posint))
local ct, pe, pm, i;
pm := key[1];
pe := key[2];
## The original used `message` instead of `msg`, which was
## a careless typo. But iterated list concatenation like this
## is inefficient. Better to just use `seq`, as below.
## Also, use inert `&^` instead of `^` in the call to `mod`
## since the latter inefficiently computes the power
## explicitly (before taking the modulus).
#ct := [];
# for i to nops(msg) do ct := [op(ct), `mod`(msg[i] &^ pe, pm)]
#end do;
ct := map(u->`mod`(u &^ pe, pm), msg);
return ct;
end proc:
# You supplied (n,e) and you'll need to find d in order to decode.
n:=26271227347;
n := 26271227347
L := numtheory[lambda](n);
L := 13135445468
e:=11546465;
e := 11546465
evalb( e < L ); # a requirement
true
evalb( gcd(e, L) = 1); # a requirement
true
d := 1/e mod L;
d := 7567915453
# Now decode the number you supplied.
res := rsa([n,d],[11393739244]);
res := [87]
with(StringTools):
# So what ASCII character is that?
convert(res,bytes);
"W"
s := "Wha":
sb := map(convert,convert(s,bytes),string);
sb := ["87", "104", "97"]
sbn := map(parse,sb);
sbn := [87, 104, 97]
encoded := rsa([n,e],sbn);
encoded := [11393739244, 9911682959, 21087186892]
decoded := rsa([n,d],encoded);
decoded := [87, 104, 97]
pad := proc(str::string)
local r;
r := irem(length(str),3);
cat(seq("0",i=1..`if`(r=0,0,3-r)), str);
end proc:
map(pad, map(convert,decoded,string));
["087", "104", "097"]
cat(op(map(u->convert(map(parse,[LengthSplit(convert(u,string),3)]),
bytes), %)));
"Wha"
newsb := [cat(op(map(SubstituteAll,map(PadLeft,sb,3)," ","0")))];
newsb := ["087104097"]
newsbn := map(parse,newsb);
newsbn := [87104097]
encoded := rsa([n,e],newsbn);
encoded := [15987098394]
decoded := rsa([n,d],%);
decoded := [87104097]
map(pad, map(convert,decoded,string));
["087104097"]
cat(op(map(u->convert(map(parse,[LengthSplit(convert(u,string),3)]),
bytes), %)));
"Wha"