VB script not returning any value - datetime

Question

Function NextMonthName(dateval)
Dim tmp : tmp = DateAdd("m", 1, dateval)
NextMonthName = MonthName(Month(tmp))
return NextMonthName
Wscript.Echo NextMonthName
End Function
Function PrevMonthName(dateval)
Dim tmp : tmp = DateAdd("m", -1, dateval)
NextMonthName = MonthName(Month(tmp))
return NextMonthName
End Function
I am running the above mentioned VB script and it completes fine without any output. I want the result in text file. I am not able to get the output in console also.

Answer 1

As there is no return in VBScript, this
Option Explicit
Function NextMonthName(dateval)
Dim tmp : tmp = DateAdd("m", 1, dateval)
NextMonthName = MonthName(Month(tmp))
return NextMonthName
End Function
WScript.Echo NextMonthName(Now)
will fail with
...\31436343.vbs(6, 5) Microsoft VBScript runtime error: Variable is undefined: 'return'
(looks like you asked a question based on code containing a global "On Error Resume Next")
Removing the offending line -
Option Explicit
Function NextMonthName(dateval)
Dim tmp : tmp = DateAdd("m", 1, dateval)
NextMonthName = MonthName(Month(tmp))
End Function
WScript.Echo NextMonthName(Now)
solves the problem:
cscript 31436343.vbs
August

Answer 2

To write the ouput into text file ;
Option Explicit
Dim Title,dateval,Message
Title = "The previous Month and The Next Month"
dateval = Now()
Message = "The previous Month : "& PrevMonthName(dateval) & " "& Year(dateval) & vbCrLf &_
"The Next Month :"& NextMonthName(dateval) & " "& Year(dateval)
MsgBox Message,VbInformation,Title
WriteLog Message
'*******************************************
Function PrevMonthName(dateval)
Dim tmp : tmp = DateAdd("m", -1, dateval)
PrevMonthName = MonthName(Month(tmp))
End Function
'*******************************************
Function NextMonthName(dateval)
Dim tmp : tmp = DateAdd("m", 1, dateval)
NextMonthName = MonthName(Month(tmp))
End Function
'*******************************************
Sub WriteLog(strText)
Dim fs,ts,LogFile
Const ForWriting = 2
LogFile = Left(Wscript.ScriptFullName, InstrRev(Wscript.ScriptFullName, ".")) & "log"
Set fs = CreateObject("Scripting.FileSystemObject")
Set ts = fs.OpenTextFile(LogFile,ForWriting,True)
ts.WriteLine strText
ts.Close
End Sub
'********************************************